;============================================================
;                                                 2010/--/--
;	Artlet2D sample
;
;============================================================
;
; さまざまなブラシを使った描画のサンプルです。
;
;============================================================

#include "a2d.hsp"

	; 仮想イメージ 0 を作成
	alCreateImage 0, 640, 480
	if stat = -1 : dialog "GDI+ を初期化できませんでした。" : end

	; ソリッドブラシ
	alColor 255, 0, 0
	alFillEllip 0, 0, 240, 120

	; 半透明ブラシ
	alColor 0, 0, 255, 128
	alFillRect 50, 50, 240, 120

	; グラデーションブラシ
	alGradientColor 100, 100, 340, 220, RGBA(255, 0, 0), RGBA(0, 0, 255)
	alFillEllip 100, 100, 240, 120

	; 半透明グラデーションブラシ
	alGradientColor 150, 150, 390, 270, RGBA(0, 255, 0, 255), RGBA(0, 255, 0, 0)
	alFillRect 150, 150, 240, 120

	; 消しゴムブラシ
	alEraserBrush
	alFillEllip 200, 200, 240, 120

	; テクスチャブラシ
	alCreateImageByFile 1, "texture.jpg"	; 画像ファイルから仮想イメージ 1 を作成します
	alSelectImage 0				; 描画先として仮想イメージ 0 を選択し直します。
	alTextureImage 1			; テクスチャブラシとして、仮想イメージ 1 を選択します。
	alFillRect 250, 250, 240, 120

	; 仮想イメージ 0 から HSP スクリーンにコピー
	alCopyImageToScreen 0, 0
	redraw