mmaudio4.hsp

sample\mmaudio\mmaudio4.hsp » Plain Format

#use strict
#use hsp3dish,mod_mmaudio,mod_tamakeisd

;	mod_mmaudioモジュールサンプル(4)
;	(Windows Vista以降で動作します)
;	PC上で再生されているサウンドに合わせて珠音ちゃんの口が動きます
;	(Windows上で再生したデバイスの音をもとに取得します)
;	珠音ちゃん・プロ生ちゃん SD 上半身コラボ素材（イラスト: らぐほのえりか）
;	暮井 慧（プロ生ちゃん）(C) Pronama LLC
;

	screen 0,640,480
	chr=1			; キャラID
	randomize
*start
	;	SDキャラの準備
	;	sdchr_load p1, p2, p3
	;
	;	p1(0) : キャラID(0=慧/1=珠音/2=フィネス/3=千由莉)
	;	p2(0) : 向き(0=右/1=左)
	;	p3(0) : サイズ%(0=100%)
	;
	cls
	sdchr_load 0,0,50	; 素材の指定
	sdchr_load chr,1,50	; 素材の指定

	;button "キャラ変更",*chrchange

	mepati=0		; 目のアニメーション
	mepati2=40		; 目のアニメーション
	kutipaku=0		; 口のアニメーション
	kutiwait=0
	key=0
*main
	peak = GetPeakValue()				; ピーク値を取得する
	if peak<0 : dialog "Function Failed" : end	; エラーが発生した
	i=int(peak*100)					; ピーク値を0〜100の値に変換する

	stick key
	if key&16 : kutiwait=4	; スペースキーで口を動かします(テスト用)
	if kutiwait=0 {
		if i>0 {
			kutiwait=2+rnd(3)
		}
	}

	redraw 0

	pos 320,0

	mepati++:i=mepati\60
	if i>2 : i=0
	j=0
	if kutiwait>0 {
		kutiwait--:j=1
		if kutiwait>2 : j=0
	}
	sdchr_put chr,0,i,j		; 素材の表示

	pos -40,0
	mepati2++:i=mepati2\55
	if i>2 : i=0
	sdchr_putex 0,7		; 素材の表示

	redraw 1
	await 1000/30
	goto *main

*chrchange
	;	キャラ変更
	chr++
	if chr>3 : chr=0
	goto *start